IF OBJECT_ID('dbo.sp_fdt_reapertura_embargos_ns') IS NOT NULL
    DROP PROCEDURE dbo.sp_fdt_reapertura_embargos_ns
GO
CREATE PROCEDURE dbo.sp_fdt_reapertura_embargos_ns
(  
    @pch_compania      char(4),  
    @psi_id_calendario smallint  
)  
/*********************************************************************/  
/*** Modulo:      Módulo Fiscal Colombiano - Embargos              ***/  
/*** Descripcion: Actualiza saldos y controla situacion            ***/  
/*** Autor:   Juan Carlos Leguizamon                           ***/  
/*** Fecha:   Junio 5 de 2002                                  ***/  
/*** Revisiones: Sep-22-06 Por si el mismo embargo queda en mas de un registro ***/  
/***             Mar-03-07 Solo reactivar embargos inactivados en el periodo ***/  
/*********************************************************************/  
AS  
BEGIN  
    SELECT tra = trabajador, con = concepto, sec = factor_02, imp = sum(importe)  
    INTO #embargos  
    FROM transacciones_ns a  
    WHERE compania = @pch_compania  
      AND id_calendario = @psi_id_calendario  
      AND EXISTS (SELECT 1 FROM fdt_embargos x  
                  WHERE x.compania = a.compania   
                    AND x.trabajador = a.trabajador  
                    AND x.secuencia = a.factor_02  
                    AND x.monto_total > 0)  
   GROUP BY trabajador, concepto, factor_02  
  
    UPDATE fdt_embargos  
    SET saldo_actual = saldo_actual + imp  
    FROM #embargos  
    WHERE trabajador = tra  
      AND concepto = con  
      AND secuencia = sec  
      AND compania = @pch_compania  
      AND monto_total > 0  
  
   /* 16 DE FEBRERO DE 2007 Esto lo corrigió Yenenia para Grasco */
    UPDATE fdt_embargos    
    SET situacion = 1, fecha_baja = NULL    
    FROM #embargos
    WHERE compania = @pch_compania     
      AND trabajador = tra    
      AND concepto = con    
      AND secuencia = sec    
      AND monto_total > 0    
      AND situacion = 2    
      AND saldo_actual > 0    

    DROP TABLE #embargos    
END  
GO
GRANT EXECUTE ON dbo.sp_fdt_reapertura_embargos_ns TO PUBLIC
GO
