IF OBJECT_ID('dbo.vw_fco_integrada_rt01') IS NOT NULL
    DROP VIEW dbo.vw_fco_integrada_rt01
GO
CREATE VIEW dbo.vw_fco_integrada_rt01
AS
/*************************************************************************/
-- Modulo Fiscal Colombiano 2.0 ADAM V3
-- Descripcion: Archivo Plano Planilla Integrada Registro Tipo 1
-- Autor: Juan Carlos Leguizamon
-- Fecha: Junio 2005
-- Revisiones:
-- JCL 27-AGO-07 Inclusión del campo tipo_planilla
/*************************************************************************/
SELECT
    compania, anio, mes, sucursal, tipo_planilla,
    '01' + RIGHT('00000' + RTRIM(secuencia), 5) + CONVERT(char(200), razon_social) +
    tipo_documento + CONVERT(char(16), nro_id) + dv + tipo_planilla + 
    '0000000000' + -- JCL Ajuste de junio 21/06
    Space(10) +
    ISNULL((select forma_presentacion from vw_fco_companias x where x.compania = a.compania), 'C') + -- JCL Ajuste Oct-30-06
    sucursal + CONVERT(char(40), nombre_sucursal) + 
    CONVERT(char(6), nueva_ARP) + 
    Left(periodo, 4) + '-' + Right(periodo, 2) + -- JCL Ajuste de junio 21/06
    Left(periodo_salud, 4) + '-' + Right(periodo_salud, 2) + -- JCL Ajuste de junio 21/06
    CONVERT(char(10), nro_radicacion) + 
    Convert(char(10), getdate(), 120) + -- JCL Ajuste de junio 21/06
    RIGHT('00000' + RTRIM(nro_empleados), 5) + 
    RIGHT('000000000000' + RTRIM(valor_nomina), 12) + '1' +
    operador AS registro1
FROM fco_integrada_cab a
WHERE tipo_planilla <> 'Y'
UNION
SELECT
    a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla,
    '01' + RIGHT('00000' + RTRIM(a.secuencia), 5) + CONVERT(char(200), a.razon_social) +
    a.tipo_documento + CONVERT(char(16), a.nro_id) + a.dv + a.tipo_planilla + 
    Right('0000000000' + LTRIM(RTRIM(IsNull(b.nro_planilla, '0'))), 10) + 
    IsNull(Convert(char(10), b.fecha_pago_real, 120), Space(10)) +
    ISNULL((select forma_presentacion from vw_fco_companias x where x.compania = a.compania), 'C') + -- JCL Ajuste Oct-30-06
    a.sucursal + CONVERT(char(40), a.nombre_sucursal) + 
    CONVERT(char(6), a.nueva_ARP) + 
    Left(a.periodo_salud, 4) + '-' + Right(a.periodo_salud, 2) + -- JCL Ajuste de junio 21/06
    Left(a.periodo_salud, 4) + '-' + Right(a.periodo_salud, 2) + -- JCL Ajuste de junio 21/06
    CONVERT(char(10), a.nro_radicacion) + 
    Convert(char(10), getdate(), 120) + -- JCL Ajuste de junio 21/06
    RIGHT('00000' + RTRIM(a.nro_empleados), 5) + 
    RIGHT('000000000000' + RTRIM(a.valor_nomina), 12) + '1' +
    a.operador AS registro1
FROM fco_integrada_cab a
LEFT JOIN fco_integrada_cab b ON a.compania = b.compania And a.anio = b.anio And a.mes = b.mes And a.sucursal = b.sucursal
  And b.tipo_planilla = 'E'
WHERE a.tipo_planilla = 'Y'
GO
GRANT SELECT ON dbo.vw_fco_integrada_rt01 TO PUBLIC
GO


