If Object_Id('dbo.vw_fco_totales_autoliq') Is Not Null
    Drop View dbo.vw_fco_totales_autoliq
Go
Create View dbo.vw_fco_totales_autoliq
As
Select 
    grupo = 'FONDOS DE PENSIONES', 
    a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla, a.cod_AFP, 
    b.descripcion As nombre_adm, 
    a.total_afiliados, a.suma_aportes, a.suma_voluntarios, a.suma_voluntarios_cia, a.suma_FSP_sol, a.suma_FSP_sub, 
    upc_adicional = 0, ige = 0, lma = 0, incapacidades_arp = 0, saf = 0, a.total_pagar
From fco_integrada_rt03 a
Inner Join vw_fco_administradoras b On a.compania = b.compania And a.cod_AFP = b.codigo
Where b.tipo = 'AFP'
Union
Select 
    grupo = 'ENTIDADES PROMOTORAS DE SALUD', 
    a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla, a.cod_EPS, 
    b.descripcion, a.total_afiliados, a.suma_aportes, 0, 0, 0, 0, 
    suma_UPC, suma_aut_IGE, suma_aut_LMA, 0, saldo_favor_aportes + saldo_favor_UPC, a.total_pagar
From fco_integrada_rt04 a
Inner Join vw_fco_administradoras b On a.compania = b.compania And a.cod_EPS = b.codigo
Where b.tipo = 'EPS'
Union
Select grupo = 'ADMINISTRADORA DE RIESGOS PROFESIONALES',
    a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla, a.cod_ARP, b.nombre_ARP,
    a.total_afiliados, a.suma_aportes, 0, 0, 0, 0, 0, 0, 0, incapacidades + otros_riesgos, saldo_favor, total_pagar
From fco_integrada_rt05 a
Inner Join vw_fco_cias_datos_adi b On a.compania = b.compania
Union
Select grupo = 'CAJAS DE COMPENSACIÓN FAMILIAR',
    a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla, a.cod_CCF, b.descripcion,
    Count(Distinct a.trabajador), Sum(a.aporte_CCF), 0, 0, 0, 0, 0, 0, 0, 0, 0, Sum(a.aporte_CCF)
From fco_integrada_det a
Inner Join vw_fco_administradoras b On a.compania = b.compania And a.cod_CCF = b.codigo
Where b.tipo = 'CCF'
And a.cod_CCF <> ''
Group By a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla, a.cod_CCF, b.descripcion
Union
Select grupo = 'SERVICIO NACIONAL DE APRENDIZAJE',
    a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla, 'SENA', 'SENA',
    Count(Distinct a.trabajador), Sum(a.aporte_SENA), 0, 0, 0, 0, 0, 0, 0, 0, 0, Sum(a.aporte_SENA)
From fco_integrada_det a
Where a.cod_CCF <> ''
Group By a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla
Union
Select grupo = 'INSTITUTO COLOMBIANO DE BIENESTAR FAMILIAR',
    a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla, 'ICBF', 'ICBF',
    Count(Distinct a.trabajador), Sum(a.aporte_ICBF), 0, 0, 0, 0, 0, 0, 0, 0, 0, Sum(a.aporte_ICBF)
From fco_integrada_det a
Where a.cod_CCF <> ''
Group By a.compania, a.anio, a.mes, a.sucursal, a.tipo_planilla
Go
Grant Select On dbo.vw_fco_totales_autoliq To Public
Go
